ActionScript-driven Example

var avatarSWF:Object;

var loader:Loader = new Loader();
loader.scaleX = 0.5;
loader.scaleY = 0.5;
loader.y = 50;
addChild(loader);

loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderCompleteHandler, false, 0, true);
loader.load(new URLRequest("myavatarcharacter.swf"));

function loaderCompleteHandler(event:Event):void {
	avatarSWF = loader.content;
	avatarSWF.initialize();
	initializeInterface();
}
function initializeInterface():void {
	initializeSliders();
	updateSliders();
	randomizeButton.addEventListener(MouseEvent.CLICK, randomizeHandler);
}
function initializeSliders():void {
	initializeSlider(hairType, 0, 71);
	initializeSlider(eyebrowType, 0, 23);
	initializeSlider(eyeType, 0, 47);
	initializeSlider(glassesType, 0, 8);
	initializeSlider(noseType, 0, 11);
	initializeSlider(mouthType, 0, 23);
}
function initializeSlider(slider:MovieClip, min:int, max:int):void {
	slider.valueMin = min;
	slider.valueMax = max;
	slider.addEventListener(Event.CHANGE, sliderChangedHandler);
	slider.addEventListener(Event.COMPLETE, refresh);
}
function updateSliders():void {
	updateSlider(hairType);
	updateSlider(eyebrowType);
	updateSlider(eyeType);
	updateSlider(glassesType);
	updateSlider(noseType);
	updateSlider(mouthType);
}
function updateSlider(slider:MovieClip):void {
	slider.setValue(int(avatarSWF.getAvatarValue(slider.name)));
}
function sliderChangedHandler(event:Event):void {
	avatarSWF.setAvatarValue(event.currentTarget.name, event.currentTarget.value);
	avatarSWF.draw(true);
}
function randomizeHandler(event:MouseEvent):void {
	avatarSWF.randomizeAvatar();
	avatarSWF.draw();
	updateSliders();
}
function refresh(event:Event):void {
	avatarSWF.draw();
}